添加链接 注册    登录
link管理
链接快照平台
  • 输入网页链接，自动生成快照
  • 标签化管理网页链接
相关文章推荐
道上混的甜瓜  ·  最新整理！全国工程设计综合资质甲级企业名录（ ...·  4 月前    · 
温柔的滑板  ·  因果推理如果落地？看这份KDD2021微软/ ...·  5 月前    · 
傻傻的大蒜  ·  Asp.Net ...·  1 年前    · 
深沉的黄瓜  ·  家族式前脸设计 疑似比亚迪驱逐舰 07 ...·  1 年前    · 
绅士的石榴  ·  5v车充价格报价行情 - 京东·  1 年前    · 
link管理  ›  Multimedia - Capturing Images - 《Qt6 QML Book》 - 书栈网 · BookStack
qml
https://www.bookstack.cn/read/qt6-qml-book/7db93ce13c44b38e.md
忧郁的作业本
1 年前

Capturing Images

One of the key features of the Camera element is that is can be used to take pictures. We will use this in a simple stop-motion application. By building the application, you will learn how to show a viewfinder, switch between cameras, snap photos and keep track of the pictures taken.

The user interface is shown below. It consists of three major parts. In the background, you will find the viewfinder, to the right, a column of buttons and at the bottom, a list of images taken. The idea is to take a series of photos, then click the Play Sequence button. This will play the images back, creating a simple stop-motion film.

The viewfinder

The viewfinder part of the camera is made using a VideoOutput element as video output channel of a CaptureSession . The CaptureSession in turns uses a Camera component to configure the device. This will display a live video stream from the camera. 

  1. CaptureSession {
  2.     id: captureSession
  3.     videoOutput: output
  4.     camera: Camera {} 
  5.     imageCapture: ImageCapture {
  6.         /* ... */
  7.     }
  8. }
  10. VideoOutput {
  11.     id: output
  12.     anchors.fill: parent
  13. }

TIP

You can have more control on the camera behaviour by using dedicated Camera properties such as exposureMode , whiteBalanceMode or zoomFactor .

The captured images list

The list of photos is a ListView oriented horizontally that shows images from a ListModel called imagePaths . In the background, a semi-transparent black Rectangle is used. 

  1. ListModel {
  2.     id: imagePaths
  3. }
  5. ListView {
  6.     id: listView
  8.     anchors.left: parent.left
  9.     anchors.right: parent.right
  10.     anchors.bottom: parent.bottom
  11.     anchors.bottomMargin: 10
  13.     height: 100
  15.     orientation: ListView.Horizontal
  16.     spacing: 10
  18.     model: imagePaths
  20.     delegate: Image {
  21.         height: 100
  22.         source: path
  23.         fillMode: Image.PreserveAspectFit
  24.     }
  26.     Rectangle {
  27.         anchors.fill: parent
  28.         anchors.topMargin: -10
  30.         color: "black"
  31.         opacity: 0.5
  32.     }
  33. }

For the shooting of images, the CaptureSession element contains a set of sub-elements for various tasks. To capture still pictures, the CaptureSession.imageCapture element is used. When you call the captureToFile method, a picture is taken and saved in the user’s local pictures directory. This results in the CaptureSession.imageCapture emitting the imageSaved signal. 

  1. Button {
  2.     id: shotButton
  4.     width: parent.buttonWidth
  5.     height: parent.buttonHeight
  7.     text: qsTr("Take Photo")
  8.     onClicked: {
  9.         captureSession.imageCapture.captureToFile()
  10.     }
  11. }

In this case, we don’t need to show a preview image, but simply add the resulting image to the ListView at the bottom of the screen. Shown in the example below, the path to the saved image is provided as the path argument with the signal. 

  1. CaptureSession {
  2.     /* ... */
  3.     imageCapture: ImageCapture {
  4.         onImageSaved: function (id, path) {
  5.             imagePaths.append({"path": path})
  6.             listView.positionViewAtEnd()
  7.         }
  8.     }
  9. }

TIP

For showing a preview, connect to the imageCaptured signal and use the preview signal argument as source of an Image element. An id signal argument is sent along both the imageCaptured and imageSaved . This value is returned from the capture method. Using this, the capture of an image can be traced through the complete cycle. This way, the preview can be used first and then be replaced by the properly saved image. This, however, is nothing that we do in the example.

Switching between cameras

If the user has multiple cameras, it can be handy to provide a way of switching between those. It’s possible to achieve this by using the MediaDevices element in conjunction with a ListView . In our case, we’ll use a ComboBox component: 

  1. MediaDevices {
  2.     id: mediaDevices
  3. }
  5. ComboBox {
  6.     id: cameraComboBox
  8.     width: parent.buttonWidth
  9.     height: parent.buttonHeight
  11.     model: mediaDevices.videoInputs
  12.     textRole: "description"
  14.     displayText: captureSession.camera.cameraDevice.description
  16.     onActivated: function (index) {
  17.         captureSession.camera.cameraDevice = cameraComboBox.currentValue
  18.     }
  19. }

The model property of the ComboBox is set to the videoInputs property of our MediaDevices . This last property contains the list of usable video inputs. We then set the displayText of the control to the description of the camera device ( captureSession.camera.cameraDevice.description ).

Finally, when the user switches the video input, the cameraDevice is updated to reflect that change: captureSession.camera.cameraDevice = cameraComboBox.currentValue .

The playback

The last part of the application is the actual playback. This is driven using a Timer element and some JavaScript. The _imageIndex variable is used to keep track of the currently shown image. When the last image has been shown, the playback is stopped. In the example, the root.state is used to hide parts of the user interface when playing the sequence. 

  1. property int _imageIndex: -1
  3. function startPlayback() {
  4.     root.state = "playing"
  5.     setImageIndex(0)
  6.     playTimer.start()
  7. }
  9. function setImageIndex(i) {
  10.     _imageIndex = i
  12.     if (_imageIndex >= 0 && _imageIndex < imagePaths.count) {
  13.         image.source = imagePaths.get(_imageIndex).path
  14.     } else {
  15.         image.source = ""
  16.     }
  17. }
  19. Timer {
  20.     id: playTimer
  22.     interval: 200
  23.     repeat: false
  25.     onTriggered: {
  26.         if (_imageIndex + 1 < imagePaths.count) {
  27.             setImageIndex(_imageIndex + 1)
  28.             playTimer.start()
  29.         } else {
  30.             setImageIndex(-1)
  31.             root.state = ""
  32.         }
  33.     }
  34. }
 
推荐文章
道上混的甜瓜  ·  最新整理！全国工程设计综合资质甲级企业名录（88家,2022年1月30日） 截止2022年1月30日，全国共有88家综甲设计院。 北京最多，其次是湖北，再次是上海。 大部分为央企，地_水
4 月前
温柔的滑板  ·  因果推理如果落地？看这份KDD2021微软/uber《因果推理机器学习:CausalML与EconML》教程，附Slides - 专知VIP
5 月前
傻傻的大蒜  ·  Asp.Net Razor中查询数据库并显示数据的代码_tozgb的技术博客_51CTO博客
1 年前
深沉的黄瓜  ·  家族式前脸设计 疑似比亚迪驱逐舰 07 实车曝光_新闻_新出行
1 年前
绅士的石榴  ·  5v车充价格报价行情 - 京东
1 年前
Link管理   ·   51好读   ·   Sov5搜索   ·   小百科
link管理 - 链接快照平台